JSON.render: def of qasim-bend-kit@0.1.0.2
Import: import qasim-bend-kit@0.1.0.2/libs/JSON.bend as JSON
Lines 289-313 of qasim-bend-kit@0.1.0.2/libs/JSON.bend: https://jend.leeeet.dev/read.txt?path=qasim-bend-kit@0.1.0.2/libs/JSON.bend&start_line=289&end_line=313

import Base

def render(value: Value, members: BoolType(), suffix: String) -> String:
    match value:
        case Null{}: "null" ++ suffix
        case Bool{truth}:
            match truth:
                case True{}: "true" ++ suffix
                case False{}: "false" ++ suffix
        case Number{lexeme, certificate}: lexeme ++ suffix
        case Str{text}: "\"" ++ escape_string(text) ++ "\"" ++ suffix
        case Arr{Nil{}}:
            match members:
                case False{}: "[]" ++ suffix
                case True{}: "]" ++ suffix
        case Arr{head <> tail}:
            match members:
                case False{}: "[" ++ render(head, False{}, render(Arr{tail}, True{}, suffix))
                case True{}: "," ++ render(head, False{}, render(Arr{tail}, True{}, suffix))
        case Obj{Nil{}}:
            match members:
                case False{}: "{}" ++ suffix
                case True{}: "}" ++ suffix
        case Obj{(key, value) <> tail}:
            match members:
                case False{}: render_object_field("{", key, render(value, False{}, render(Obj{tail}, True{}, suffix)))
                case True{}: render_object_field(",", key, render(value, False{}, render(Obj{tail}, True{}, suffix)))

Uses (9):
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=Bool
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=List
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=Sigma
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=String
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=String.append
  https://jend.leeeet.dev/definition.txt?path=qasim-bend-kit@0.1.0.2/libs/JSON.bend&name=BoolType
  https://jend.leeeet.dev/definition.txt?path=qasim-bend-kit@0.1.0.2/libs/JSON.bend&name=Value
  https://jend.leeeet.dev/definition.txt?path=qasim-bend-kit@0.1.0.2/libs/JSON.bend&name=escape_string
  https://jend.leeeet.dev/definition.txt?path=qasim-bend-kit@0.1.0.2/libs/JSON.bend&name=render_object_field