Json.Json.show: def of bend-kube-runtime@0.2.0.0
Import: import bend-kube-runtime@0.2.0.0/src/json.bend as Json
Lines 266-293 of bend-kube-runtime@0.2.0.0/src/json.bend: https://jend.leeeet.dev/read.txt?path=bend-kube-runtime@0.2.0.0/src/json.bend&start_line=266&end_line=293

import Base

# The compact text of a value. Inside a chain, the first element prints
# bare and the rest follow a comma.
def Json.show(j: Json) -> String:
  match j:
    case JNull{}:
      "null"
    case JBool{True{}}:
      "true"
    case JBool{False{}}:
      "false"
    case JNum{s}:
      s
    case JStr{s}:
      Json.quote(s)
    case JArr{xs}:
      "[" ++ Json.show(xs) ++ "]"
    case JObj{ms}:
      "{" ++ Json.show(ms) ++ "}"
    case JNil{}:
      ""
    case JCons{h, JNil{}}:
      Json.show(h)
    case JCons{h, t}:
      Json.show(h) ++ "," ++ Json.show(t)
    case JMem{k, v, JNil{}}:
      Json.quote(k) ++ ":" ++ Json.show(v)
    case JMem{k, v, t}:
      Json.quote(k) ++ ":" ++ Json.show(v) ++ "," ++ Json.show(t)

Uses (5):
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=Bool
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=String
  https://jend.leeeet.dev/definition.txt?path=Base/base.bend&name=String.append
  https://jend.leeeet.dev/definition.txt?path=bend-kube-runtime@0.2.0.0/src/json.bend&name=Json
  https://jend.leeeet.dev/definition.txt?path=bend-kube-runtime@0.2.0.0/src/json.bend&name=Json.quote